10 REM BUSINESS TRIP BY KENNY LAWSON
20 FORX=1TO10:READA$:CN$(X)=A$:NEXT
30 FORX=828TO935:READA:POKEX,A:NEXT
40 W1$="                             ":W2$=W1$+"[144] "
50 W3$="[144]"+RIGHT$(W1$,30):MM$="   "+CHR$(18)+CHR$(129)+MID$(W1$,3,18)+"[146]   "
60 W4$="[156]                     ":W5$=W4$+"[144] ":DY=0:FI$="EXPENSE.SQ"
70 W6$=LEFT$(W3$,23):CH$="CHOOSEANOPTION":SV=0:DIMZ$(23)
80 FORX=1TO10:FORC=1TO16-LEN(CN$(X)):CN$(X)=CN$(X)+CHR$(32):NEXTC
90 CN$(X)=CHR$(32)+CN$(X):NEXTX:DL$="[164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164]"
100 L1$="[175][175][146]":L2$="[185][185][146]":L3$="[162][162][146]":L4$="[184][184][146]":L5$="[183][183][146]"
110 BC$="  [146][145][157][157]":TA$="                     "
120 TA(1)=9:FORX=2TO10:TA(X)=TA(X-1)+3:NEXT
130 CO$(1)="":CO$(2)="[156]":CO$(3)="":CO$(4)="":CO$(5)="[154]"
140 CO$(6)="[129]":CO$(7)="[149]":CO$(8)="[153]":CO$(9)="[150]":CO$(10)="[151]"
150 OPEN15,8,15:OPEN8,8,8,FI$+",S,R":INPUT#15,ER$:BB$="0":ED=0
160 IFVAL(ER$)<19THENCLOSE8:CLOSE15:GOTO190
170 PRINT#15,"UJ":FORX=1TO2000:NEXT:CLOSE15
180 CLOSE8:OPEN8,8,8,FI$+",S,W":FORX=1TO10:PRINT#8,BB$:NEXT:CLOSE8:CLOSE15
190 PRINTCHR$(30)CHR$(147):POKE53280,15:POKE53281,15
200 PRINT"[129][207][180]"TAB(37)"[170][208]"
210 PRINT"[208][183][183][183][183][183][183][183][183][183][183][183][183][183][183][183][183][183][183][183][183][183][183][183][183][183][183][183][183][183][183][183][183][183][183][183][183][183][207]"
220 FORX=1TO20:PRINT"[167]"TAB(38)"[180]":NEXT
230 PRINT"[186][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][204]"
240 PRINT"[204][180]"TAB(37)"[170][186]";
250 PRINTCHR$(19):PRINT:PRINT:PRINT"[129]BUSINESS DIARY AND EXPENSE CHART"
260 PRINTTAB(8)MM$:PRINTTAB(8)"       MAIN  MENU    [146]   "
270 FORX=1TO2:PRINTTAB(8)MM$:NEXT:PRINTTAB(8)"    1. LOAD THE FILE [146]   "
280 PRINTTAB(8)"    2. SAVE THE FILE [146]   "
290 PRINTTAB(8)"    3. ENTER AMOUNTS [146]   "
300 PRINTTAB(8)"    4. SEE BAR CHART [146]   "
310 PRINTTAB(8)"    5. CHECK TOTALS  [146]   "
320 PRINTTAB(8)"    6. EXIT PROGRAM  [146]   "
330 FORX=1TO4:PRINTTAB(8)MM$:NEXT:PRINT"[145][145][145]"
340 PRINTTAB(11)CH$:GETA$
350 IFA$<>""THEN370
360 FORX=1TO300:NEXT:PRINT"[145][145]":PRINTTAB(8)MM$"[145]":FORX=1TO300:NEXT:GOTO340
370 A=VAL(A$):IFA<1ORA>6THEN360
380 ONAGOTO690,790,400,1100,1560,1670
390 REM GET CATEGORY INPUTS
400 POKE53280,14:POKE53281,14:PRINTCHR$(159)CHR$(147)CHR$(17)
410 A$=CHR$(18)+CHR$(32):PRINTTAB(11);:FORX=1TO19:PRINTA$;:NEXT:PRINT
420 FORX=1TO21:PRINTTAB(11)A$SPC(17)A$:NEXT
430 PRINTTAB(11);:FORX=1TO19:PRINTA$;:NEXT:PRINTCHR$(19):FORX=1TO3:PRINT:NEXT
440 FORX=1TO10:PRINTTAB(12)CN$(X)CHR$(17):NEXT
450 PRINT"":PRINTTAB(12)CHR$(18)CN$(1)
460 PRINT""TAB(32)"USE THE"
470 PRINT" BUSINESS"TAB(32)"CURSOR":PRINT"  DIARY"TAB(32)"KEYS TO"
480 PRINT"   AND"TAB(32)"MOVE":PRINT" EXPENSE":PRINTTAB(32)"RETURN"
490 PRINT"  CHART":PRINTTAB(34)"TO":PRINTTAB(32)"SELECT"
500 PRINTTAB(32)"<M> FOR":PRINTTAB(33)"MENU":POKE214,3:PRINT
510 GETA$:IFA$=""THEN510
520 IFA$="M"THEN190
530 IFA$<>CHR$(17)THEN590
540 GOSUB870:IFCN=10THEN570
550 PRINT:PRINTCHR$(145)TAB(12)CN$(CN)CHR$(17)
560 PRINTTAB(12)CHR$(18)CN$(CN+1);:GOTO510
570 PRINT:PRINTCHR$(145)TAB(12)CN$(CN):POKE214,3:PRINT:PRINTTAB(12)""CN$(1);
580 GOTO510
590 IFA$<>CHR$(145)THEN650
600 GOSUB870:IFCN=1THEN630
610 PRINT:PRINTCHR$(145)TAB(12)CN$(CN):POKE214,SN-3:PRINT
620 PRINTTAB(12)CHR$(18)CN$(CN-1);:GOTO510
630 PRINT:PRINTCHR$(145)TAB(12)CN$(1):POKE214,21:PRINT
640 PRINTTAB(12)CHR$(18)CN$(10);:GOTO510
650 IFA$<>CHR$(13)THEN510
660 GOSUB870:RO=PEEK(214):SYS828:REM SAVE SCREEN
670 GOSUB980:REM INPUT ROUTINE
680 GOTO510
690 REM LOAD FILE
700 GOSUB770:REM DRAW WINDOW
710 PRINTTAB(9)"[156][145]LOADING"FI$:GOSUB1410:REM READ DISK STATUS
720 CLOSE8:OPEN8,8,8,"EXPENSE.SQ,S,R"
730 FORX=1TO10:INPUT#8,CS$(X):CN(X)=VAL(CS$(X)):NEXT:CLOSE8
740 FORX=1TO10:IFCN(X)<>0THENDY=1
750 NEXT
760 GOSUB1410:GOTO250
770 PRINT"":PRINTTAB(9)W4$:FORX=1TO3:PRINTTAB(9)W5$:NEXT
780 PRINTTAB(10)W6$"[145][145][145][145]":RETURN
790 REM SAVE FILE
800 OPEN15,8,15,"S0:BUS.SEQ.DEL"
810 GOSUB770:PRINTTAB(10)"[156][145]SAVING"FI$
820 GOSUB1410:OPEN15,8,15,"R0:BUS.SEQ.DEL="+FI$
830 GOSUB1410:OPEN15,8,15,"S0:"+FI$
840 GOSUB1410:CLOSE8:OPEN8,8,8,FI$+",S,W"
850 FORX=1TO10:CS$(X)=STR$(CN(X)):PRINT#8,CS$(X):NEXT
860 GOSUB1410:SV=1:GOTO250
870 REM CHECK PEEK
880 SN=PEEK(214):IFSN=4THENCN=1:RETURN
890 IFSN=6THENCN=2:RETURN
900 IFSN=8THENCN=3:RETURN
910 IFSN=10THENCN=4:RETURN
920 IFSN=12THENCN=5:RETURN
930 IFSN=14THENCN=6:RETURN
940 IFSN=16THENCN=7:RETURN
950 IFSN=18THENCN=8:RETURN
960 IFSN=20THENCN=9:RETURN
970 CN=10:RETURN
980 REM INPUT ROUTINE
990 GOSUB1470:TP$="":PRINTCHR$(31);
1000 POKE204,0:GETD$:IFD$=""THEN1000
1010 IFD$="."THEN1050
1020 IFD$=CHR$(13)THEN1050
1030 IFD$>"/"ANDD$<":"THEN1050
1040 WAIT207,1:POKE204,1:GOSUB1790:GOSUB1510:GOTO990
1050 IFD$<>CHR$(13)THENTP$=TP$+D$:PRINTD$;:GOTO1000
1060 WAIT207,1:POKE204,1
1070 CN(CN)=CN(CN)+VAL(TP$):PRINTCHR$(159):IFCN(CN)<>0THENDY=1
1080 SYS882:POKE214,RO-1:PRINT:IFTP$<>""THENED=1
1090 RETURN
1100 REM DRAW BAR CHART
1110 IFDYTHEN1140
1120 GOSUB1790:GOSUB770:PRINTTAB(9)"[156]NO DATA IN CATEGORIES"
1130 FORX=1TO2000:NEXT:GOTO250
1140 POKE53280,0:POKE53281,0:PRINTCHR$(30)CHR$(147);
1150 HI=0:FORX=1TO10:IFCN(X)>HITHENHI=INT(CN(X))
1160 NEXT
1170 IFHI/20<>INT(HI/20)THENHI=HI+1:GOTO1170
1180 IN=INT(HI/20):SA=HI-IN
1190 FORX=SATO0STEP-IN:PRINT"$ "X;TAB(8)DL$:NEXT
1200 PRINTTAB(9)"D  E  H  M  P  S  T  G  T  V"
1210 PRINT"CATEGORY I  N  T  S  H  U  A  R  R  M"
1220 PRINTTAB(9)"N  T  L  C  O  P  X  A  A  T"
1230 PRINT"         WORKING....PLEASE WAIT        "
1240 PN=IN/6:FORX=1TO10:CH(X)=INT(CN(X)/IN):CL(X)=CN(X)-CH(X)*IN
1250 IFCL(X)=0THENPB$(X)="":GOTO1320
1260 IFCL(X)=<PNTHENPB$(X)=L1$:GOTO1320
1270 IFCL(X)=<PN*2THENPB$(X)=L2$:GOTO1320
1280 IFCL(X)=<PN*3THENPB$(X)=L3$:GOTO1320
1290 IFCL(X)=<PN*4THENPB$(X)=L4$:GOTO1320
1300 IFCL(X)=<PN*5THENPB$(X)=L5$:GOTO1320
1310 CH(X)=CH(X)+1
1320 NEXT
1330 FORX=1TO10:LT=0:POKE214,18:PRINT:PRINTTAB(TA(X));
1340 IFCH(X)=0THEN1360
1350 FORCT=1TOCH(X):PRINTCO$(X)BC$;:NEXT
1360 PRINTCO$(X)PB$(X):NEXT
1370 POKE214,23:PRINT:PRINT"    WOULD YOU LIKE A PRINTOUT? (Y/N)   "
1380 GETA$:IFA$="Y"THEN1850
1390 IFA$<>"N"THEN1380
1400 GOTO190
1410 REM CHECK DISK STATUS
1420 CLOSE15:OPEN15,8,15:INPUT#15,V$,W$,X$,Y$
1430 IFVAL(V$)<19THENCLOSE15:RETURN
1440 GOSUB1790
1450 PRINTTAB(10)"[156]DISKERROR:":PRINTTAB(10)""W$:FORX=1TO2000:NEXT
1460 PRINT#15,"UJ":FORX=1TO1000:NEXT:CLOSE15:GOTO250
1470 REM DRAW WINDOW 1
1480 PRINT"":PRINTTAB(5)W1$:FORX=1TO6:PRINTTAB(5)W2$:NEXT
1490 PRINTTAB(6)W3$"[145][145][145][145][145][145][145]":PRINTTAB(6)"ENTERTODAY'STOTALAMOUNT"
1500 PRINTTAB(6)"FOR"CN$(CN):PRINTCHR$(17)TAB(8)"$";:RETURN
1510 REM DRAW WINDOW 2
1520 PRINT"":PRINTTAB(9)W4$:FORX=1TO3:PRINTTAB(9)W5$:NEXT
1530 PRINTTAB(10)W6$"[145][145][145][145][145][156]":PRINTTAB(10)"USEONLYNUMBERSOR"
1540 PRINTTAB(11)"DECIMALPOINT(.)"
1550 PRINTTAB(10)"RE-ENTERTHEAMOUNT":FORX=1TO2500:NEXT:RETURN
1560 REM DISPLAY TOTALS
1570 POKE53281,5:POKE53280,5:POKE646,13:PRINTCHR$(147):GT=0
1580 FORX=1TO10:PRINTTAB(5)CN$(X)TAB(25)"$";:GOSUB1630:GT=GT+CN(X)
1590 PRINTSPC(9-LE)LE$:PRINT:NEXT
1600 PRINT"TOTAL EXPENSES= $";:LE$=STR$(GT):LE=LEN(LE$):GOSUB1640
1610 PRINTLE$TAB(26)"PRESS ANY KEY[146]";:POKE198,0
1620 WAIT198,1:POKE198,0:GOTO190
1630 LE$=STR$(CN(X)):LE=LEN(LE$)
1640 IFMID$(LE$,LE-1,1)="."THENLE$=LE$+"0":LE=LE+1
1650 IFVAL(LE$)=INT(VAL(LE$))THENLE$=LE$+".00":LE=LE+3
1660 RETURN
1670 REM EXIT PROGRAM
1680 GOSUB1790:GOSUB770:PRINTTAB(10)"[156]QUIT? ARE YOU SURE?"
1690 PRINTTAB(17)"(Y/N)":POKE198,0
1700 GETA$:IFA$="N"THEN250
1710 IFA$<>"Y"THEN1700
1720 IFSV=1ORED=0THEN1770
1730 GOSUB1790:GOSUB770:PRINTTAB(11)"[156]CHANGES NOT SAVED":POKE198,0
1740 PRINTTAB(11)"STILL QUIT? (Y/N)"
1750 GETA$:IFA$="N"THEN250
1760 IFA$<>"Y"THEN1750
1770 POKE53280,14:POKE53281,6:POKE646,14:PRINTCHR$(147)
1780 POKE198,2:POKE631,32:POKE632,20:END
1790 REM WARNING NOISE
1800 VV=54272:POKEVV+23,0:POKEVV+24,15
1810 POKEVV+6,0:POKEVV+5,12:POKEVV+1,90
1820 POKEVV+3,180:FORBB=1TO5:POKEVV+4,0
1830 POKEVV+4,65:FORCC=1TO230:NEXT:NEXT
1840 POKEVV+4,0:POKEVV+24,0:RETURN
1850 REM      HARDCOPY DUMP
1860 CLOSE15:OPEN15,4,15:CLOSE15:IFST=0THEN1890
1870 POKE214,23:PRINT:PRINT"    TURN ON PRINTER AND HIT ANY KEY    ";
1880 WAIT198,1:POKE198,0:GOTO1860
1890 POKE214,23:PRINT:PRINT"POSITION PAPER TO TOP OF FORM & HIT KEY";
1900 WAIT198,1:POKE198,0:FORX=1TO10:CS$(X)=STR$(CN(X)):NEXT
1910 POKE214,23:PRINT:PRINT"      WORKING . . . PLEASE WAIT        "
1920 SA=1024:FORZ=1TO23
1930 FORX=0TO39:C=PEEK(SA+X)
1940 IFC=160THENZ$(Z)=Z$(Z)+CHR$(18)+CHR$(32)+CHR$(146):NEXT
1950 IFC=100THENC=164
1960 IFC=111THENC=175
1970 IFC=121THENC=185
1980 IFC=98THENC=162
1990 IFC=247THENZ$(Z)=Z$(Z)+CHR$(18)+CHR$(183)+CHR$(146):NEXT
2000 IFC=248THENZ$(Z)=Z$(Z)+CHR$(18)+CHR$(184)+CHR$(146):NEXT
2010 IFC<26THENC=C+64
2020 Z$(Z)=Z$(Z)+CHR$(C):NEXTX:SA=SA+40:NEXTZ
2030 CLOSE4:OPEN4,4:FORX=1TO10:PRINT#4:NEXT
2040 PRINT#4,SPC(18)CHR$(14)"BUSINESS TRIP EXPENSES"CHR$(15)
2050 FORX=1TO6:PRINT#4:NEXT:FORX=1TO20:PRINT#4,CHR$(15)SPC(20)Z$(X)CHR$(8):NEXT
2060 PRINT#4:PRINT#4,CHR$(15):FORX=21TO23:PRINT#4,SPC(20)Z$(X):NEXT
2070 FORGG=1TO5:PRINT#4:NEXT:FORX=1TO10:WW$(X)=CS$(X)
2080 LE$=WW$(X):LE=LEN(WW$(X)):GOSUB1640:WW$(X)=LE$
2090 PRINT#4,TA$CN$(X)SPC(24-LEN(CN$(X)))"$"SPC(10-LEN(WW$(X)))WW$(X)
2100 NEXT:PRINT#4:GT=0:FORX=1TO10:GT=GT+VAL(WW$(X)):NEXT
2110 PRINT#4:PRINT#4
2120 LE$=STR$(GT):LE=LEN(LE$):GOSUB1640
2130 PRINT#4,TA$" TOTAL EXPENSES ="SPC(7)"$"SPC(10-LEN(LE$))LE$
2140 PRINT#4:CLOSE4:GOTO190
2150 DATA DINING COSTS,ENTERTAINMENT,HOTEL COSTS,MISCELLANEOUS,PHONE COSTS
2160 DATA SUPPLIES,TAXES PAID,GRATUITIES,TRANSPORTATION,VEHICLE MAINT.
2170 DATA 162,0,189,0,4,157,0,192,189,0,5,157,0,193,189,0,6,157,0,194
2180 DATA 189,0,7,157,0,195,189,0,216,157,0,196,189,0,217,157,0,197
2190 DATA 189,0,218,157,0,198,189,0,219,157,0,199,232,208,205,96
2200 DATA 162,0,189,0,192,157,0,4,189,0,193,157,0,5,189,0,194,157,0,6
2210 DATA 189,0,195,157,0,7,189,0,196,157,0,216,189,0,197,157,0,217
2220 DATA 189,0,198,157,0,218,189,0,199,157,0,219,232,208,205,96